***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 07, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJ2301-AU  D  G  S
Rg     G    1t    1
EVgs 3 2t  TABLE { V(S, 1t) }
+((0, 0)
+ (0.5 , 0.52 )
+ (1   , 0.854)
+ (1.5 , 1.575)
+ (1.75, 1.9  )
+ (2   , 2.155)
+ (2.25, 2.356)
+ (2.5 , 2.5  )
+ (2.75, 2.619)
+ (3   , 2.75 )
+ (4.5 , 3.15 )
+ (10  , 3.75 )
+ (12  , 4    ))
EVgst 1 2t value = {5e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
M1      2    1    3    3    DMOS    L=1u   W=1u
.MODEL DMOS PMOS (
+  VTO = -0.713
+   KP = 8
+LEVEL =3)
Cgs     1    3    3.788e-10
Rd     D    4    2.085e-3
Dds     4    3    DDS
.MODEL     DDS    D(IS=1E-12 N=0.8 RS=5 BV=22 TBV1=2.956e-4 CJO=4.656e-11 M=0.29 VJ=0.6)
Dbody  D    3    DBODY
.MODEL   DBODY    D(IS=1E-12 N=0.8 RS=5 BV=22 TBV1=2.956e-4 TT=25n)
Ra      4    2    3.017e-2
Rs      3    5    2.085e-3
Ls      5    S    0.5n
M2      1    8    6    6   INTER
E2      8    6    4    1   2
.MODEL   INTER    PMOS(VTO=0  KP=10   LEVEL=1)
Cgdmax  7    4    30.19e-12
Rcgd    7    4    10meg
Dgd     4    6    DGD
Rdgd    4    6    10meg
.MODEL     DGD    D(M=0.71  CJO=2.851e-10   VJ=0.34)
M3      7    9    1    1   INTER
E3      9    1    4    1   -2
.ENDS
*$
